mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2025-02-24 15:06:38 +00:00
7983ecff1c
With this patch, configure time is identical no matter whether doc is enabled or not. The configuration files also now contain explicitly-listed sources with no wildcards. For the four libraries where hotdoc needs to use clang to generate the documentation (as opposed to the rest of the libraries where hotdoc uses the gir), the script will call pkg-config to determine the appropriate C flags. This means a side effect of this patch is that pkg-config files are now generated for the gstadaptivedemux and gstopencv libraries. Part-of: <https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/8312>
63 lines
1.9 KiB
Meson
63 lines
1.9 KiB
Meson
insert_sources = files('gstinsertbin.c')
|
|
insert_headers = files('gstinsertbin.h')
|
|
install_headers(insert_headers, subdir : 'gstreamer-1.0/gst/insertbin')
|
|
|
|
doc_sources = []
|
|
foreach s: insert_sources + insert_headers
|
|
doc_sources += s.full_path()
|
|
endforeach
|
|
|
|
libs_sources += {
|
|
'insertbin': pathsep.join(doc_sources)
|
|
}
|
|
|
|
gstinsertbin = library('gstinsertbin-' + api_version,
|
|
insert_sources,
|
|
c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_INSERT_BIN', '-DG_LOG_DOMAIN="GStreamer-InsertBin"'],
|
|
include_directories : [configinc, libsinc],
|
|
version : libversion,
|
|
soversion : soversion,
|
|
darwin_versions : osxversion,
|
|
install : true,
|
|
dependencies : [gst_dep],
|
|
)
|
|
|
|
library_def = {'lib': gstinsertbin}
|
|
pkg_name = 'gstreamer-insertbin-1.0'
|
|
pkgconfig.generate(gstinsertbin,
|
|
libraries : [gst_dep],
|
|
variables : pkgconfig_variables,
|
|
subdirs : pkgconfig_subdirs,
|
|
name : pkg_name,
|
|
description : 'Bin to automatically and insertally link elements',
|
|
)
|
|
|
|
gen_sources = []
|
|
if build_gir
|
|
gir = {
|
|
'sources' : insert_sources + insert_headers,
|
|
'namespace' : 'GstInsertBin',
|
|
'nsversion' : api_version,
|
|
'identifier_prefix' : 'Gst',
|
|
'symbol_prefix' : 'gst',
|
|
'export_packages' : pkg_name,
|
|
'includes' : ['Gst-1.0'],
|
|
'install' : true,
|
|
'extra_args' : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/insertbin/gstinsertbin.h'],
|
|
'dependencies' : [gst_dep]
|
|
}
|
|
library_def += {'gir': [gir]}
|
|
if not static_build
|
|
insertbin_gir = gnome.generate_gir(gstinsertbin, kwargs: gir)
|
|
library_def += {'gir_targets': library_def.get('gir_targets', []) + [insertbin_gir]}
|
|
gen_sources += insertbin_gir
|
|
endif
|
|
endif
|
|
gst_libraries += [[pkg_name, library_def]]
|
|
|
|
gstinsertbin_dep = declare_dependency(link_with : gstinsertbin,
|
|
include_directories : [libsinc],
|
|
sources: gen_sources,
|
|
dependencies : [gst_dep])
|
|
|
|
meson.override_dependency(pkg_name, gstinsertbin_dep)
|