mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2024-11-13 12:51:16 +00:00
b004464ac6
They are part of gst_dep already and we have to make sure to always have gst_dep. The order in dependencies matters, because it is also the order in which Meson will set -I args. We want gstreamer's config.h to take precedence over glib's private config.h when it's a subproject. While at it, remove useless fallback args for gmodule/gio dependencies, only gstreamer core needs it. Part-of: <https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/2031>
32 lines
1.1 KiB
Meson
32 lines
1.1 KiB
Meson
videotestsrc_deps = [video_dep, gst_dep, gst_base_dep, libm]
|
|
orcsrc = 'gstvideotestsrcorc'
|
|
if have_orcc
|
|
videotestsrc_deps += [orc_dep]
|
|
orc_h = custom_target(orcsrc + '.h',
|
|
input : orcsrc + '.orc',
|
|
output : orcsrc + '.h',
|
|
command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
|
|
orc_c = custom_target(orcsrc + '.c',
|
|
input : orcsrc + '.orc',
|
|
output : orcsrc + '.c',
|
|
command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
|
|
orc_targets += {'name': orcsrc, 'orc-source': files(orcsrc + '.orc'), 'header': orc_h, 'source': orc_c}
|
|
else
|
|
orc_h = configure_file(input : orcsrc + '-dist.h',
|
|
output : orcsrc + '.h',
|
|
copy : true)
|
|
orc_c = configure_file(input : orcsrc + '-dist.c',
|
|
output : orcsrc + '.c',
|
|
copy : true)
|
|
endif
|
|
|
|
gstvideotestsrc = library('gstvideotestsrc',
|
|
'gstvideotestsrc.c', 'videotestsrc.c', orc_c, orc_h,
|
|
c_args : gst_plugins_base_args,
|
|
include_directories: [configinc, libsinc],
|
|
dependencies : videotestsrc_deps,
|
|
install : true,
|
|
install_dir : plugins_install_dir,
|
|
)
|
|
pkgconfig.generate(gstvideotestsrc, install_dir : plugins_pkgconfig_install_dir)
|
|
plugins += [gstvideotestsrc]
|