mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2025-02-16 03:05:32 +00:00
7983ecff1c
With this patch, configure time is identical no matter whether doc is enabled or not. The configuration files also now contain explicitly-listed sources with no wildcards. For the four libraries where hotdoc needs to use clang to generate the documentation (as opposed to the rest of the libraries where hotdoc uses the gir), the script will call pkg-config to determine the appropriate C flags. This means a side effect of this patch is that pkg-config files are now generated for the gstadaptivedemux and gstopencv libraries. Part-of: <https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/8312>
63 lines
2 KiB
Meson
63 lines
2 KiB
Meson
badaudio_sources = files('gstnonstreamaudiodecoder.c', 'gstplanaraudioadapter.c')
|
|
badaudio_headers = files('gstnonstreamaudiodecoder.h', 'audio-bad-prelude.h', 'gstplanaraudioadapter.h')
|
|
install_headers(badaudio_headers, subdir : 'gstreamer-1.0/gst/audio')
|
|
|
|
doc_sources = []
|
|
foreach s: badaudio_sources + badaudio_headers
|
|
doc_sources += s.full_path()
|
|
endforeach
|
|
|
|
libs_sources += {
|
|
'audio': pathsep.join(doc_sources)
|
|
}
|
|
|
|
gstbadaudio = library('gstbadaudio-' + api_version,
|
|
badaudio_sources,
|
|
c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_AUDIO_BAD', '-DG_LOG_DOMAIN="GStreamer-AudioBad"'],
|
|
include_directories : [configinc, libsinc],
|
|
version : libversion,
|
|
soversion : soversion,
|
|
darwin_versions : osxversion,
|
|
install : true,
|
|
dependencies : [gstaudio_dep, gstbase_dep],
|
|
)
|
|
|
|
library_def = {'lib': gstbadaudio}
|
|
pkg_name = 'gstreamer-bad-audio-1.0'
|
|
pkgconfig.generate(gstbadaudio,
|
|
libraries : [gst_dep, gstbase_dep],
|
|
variables : pkgconfig_variables,
|
|
subdirs : pkgconfig_subdirs,
|
|
name : pkg_name,
|
|
description : 'Bad audio library for GStreamer elements',
|
|
)
|
|
gen_sources = []
|
|
|
|
if build_gir
|
|
gir = {
|
|
'sources' : badaudio_sources + badaudio_headers,
|
|
'namespace' : 'GstBadAudio',
|
|
'nsversion' : api_version,
|
|
'identifier_prefix' : 'Gst',
|
|
'symbol_prefix' : 'gst',
|
|
'export_packages' : pkg_name,
|
|
'includes' : ['Gst-1.0', 'GstAudio-1.0', 'GstBase-1.0'],
|
|
'install' : true,
|
|
'extra_args' : gir_init_section + ['-DGST_USE_UNSTABLE_API'],
|
|
'dependencies' : [gstbase_dep, gstaudio_dep]
|
|
}
|
|
library_def += {'gir': [gir]}
|
|
if not static_build
|
|
audio_gir = gnome.generate_gir(gstbadaudio, kwargs: gir)
|
|
library_def += {'gir_targets': library_def.get('gir_targets', []) + [audio_gir]}
|
|
gen_sources += audio_gir
|
|
endif
|
|
endif
|
|
gst_libraries += [[pkg_name, library_def]]
|
|
|
|
gstbadaudio_dep = declare_dependency(link_with : gstbadaudio,
|
|
include_directories : [libsinc],
|
|
sources: gen_sources,
|
|
dependencies : [gstaudio_dep, gstbase_dep])
|
|
|
|
meson.override_dependency(pkg_name, gstbadaudio_dep)
|