mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2024-09-17 01:20:19 +00:00
b55dfb5313
The only plugins remaining are those that haven't been ported to Meson yet, and msdk. Also, the tests are still automagic. https://bugzilla.gnome.org/show_bug.cgi?id=795107
35 lines
1,004 B
Meson
35 lines
1,004 B
Meson
openjpeg_sources = [
|
|
'gstopenjpeg.c',
|
|
'gstopenjpegdec.c',
|
|
'gstopenjpegenc.c',
|
|
]
|
|
|
|
openjpeg_cargs = []
|
|
|
|
if get_option('openjpeg').disabled()
|
|
subdir_done()
|
|
endif
|
|
|
|
openjpeg_dep = dependency('libopenjp2', version : '>=2.1', required : false)
|
|
if not openjpeg_dep.found()
|
|
# Fallback to v1.5
|
|
openjpeg_dep = dependency('libopenjpeg1', required : false)
|
|
openjpeg_cargs += ['-DHAVE_OPENJPEG_1']
|
|
endif
|
|
if not openjpeg_dep.found() and get_option('openjpeg').enabled()
|
|
error('openjpeg plugin enabled, but neither libopenjp2 nor libopenjpeg1 not found')
|
|
endif
|
|
|
|
if openjpeg_dep.found()
|
|
gstopenjpeg = library('gstopenjpeg',
|
|
openjpeg_sources,
|
|
c_args : gst_plugins_bad_args + openjpeg_cargs,
|
|
link_args : noseh_link_args,
|
|
include_directories : [configinc],
|
|
dependencies : [gst_dep, gstvideo_dep, openjpeg_dep,
|
|
gstcodecparsers_dep],
|
|
install : true,
|
|
install_dir : plugins_install_dir,
|
|
)
|
|
pkgconfig.generate(gstopenjpeg, install_dir : plugins_pkgconfig_install_dir)
|
|
endif
|