mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2024-11-15 22:01:27 +00:00
803ce6bf48
Original commit message from CVS: GST_DEBUG reorganization This is a big diff (ca 450k), containing loads of stuff: - gstinfo.[ch] complete rewrite - changing of all GST_DEBUG messages to reflect that change - reorganization of subsystem disabling - addition of gstconfig.h.in so we can track the disablings - <gst/gst.h> does not include <unistd.h> and <config.h> anymore - documentation updated for gstinfo stuff (build the docs yourself to know what changed) - bugfixes for making of the docs (files from CVS are not deleted anymore - testsuite for debugging changes in testsuite/debug expect breakage
119 lines
2.7 KiB
Text
119 lines
2.7 KiB
Text
%{
|
|
#include <math.h>
|
|
#include <ctype.h>
|
|
#include <string.h>
|
|
|
|
#include "../gst_private.h"
|
|
|
|
#include "types.h"
|
|
#include "../gstinfo.h"
|
|
#include "grammar.tab.h"
|
|
|
|
#ifdef G_HAVE_ISO_VARARGS
|
|
#define PRINT(...) GST_CAT_DEBUG (GST_CAT_PIPELINE, "flex: "__VA_ARGS__)
|
|
#elif defined(G_HAVE_GNUC_VARARGS)
|
|
#define PRINT(args...) GST_CAT_DEBUG (GST_CAT_PIPELINE, "flex: "##args)
|
|
#else
|
|
#define PRINT(args...)
|
|
#endif
|
|
|
|
#define YY_DECL int _gst_parse_yylex (YYSTYPE *lvalp)
|
|
%}
|
|
|
|
_operator [(){}.:!,;=]
|
|
_identifier [[:alpha:]][[:alnum:]\-_%]*
|
|
|
|
_char ("\\".)|([^[:space:]])
|
|
_string {_char}+|("\""([^\"]|"\\\"")*"\"")|("'"([^']|"\\\"")*"'")
|
|
|
|
_comma [[:space:]]*","[[:space:]]*
|
|
_assign [[:space:]]*"="[[:space:]]*
|
|
|
|
/* we must do this here, because nearly everything matches a {_string} */
|
|
_assignment {_identifier}{_assign}{_string}
|
|
|
|
/* get pad/element references and stuff with dots right */
|
|
_padref "."{_identifier}
|
|
_ref {_identifier}"."{_identifier}?
|
|
_binref {_identifier}[[:space:]]*"."[[:space:]]*"("
|
|
|
|
/* links */
|
|
_capschar ("\\".)|([^[:space:]\;!\.\,\(\)\]\[])
|
|
_capsstring {_capschar}+|("\""([^\"]|"\\\"")*"\"")|("'"([^']|"\\\"")*"'")
|
|
_mimetype ({_capschar}+"/"{_capschar}+)|("\""([^\"]|"\\\"")*"\"")|("'"([^']|"\\\"")*"'")
|
|
_caps {_mimetype}(","[^!]|{_capsstring})*
|
|
_link ("!"[[:space:]]*{_caps}([[:space:]]*";"[[:space:]]*{_caps})*[[:space:]]*"!")|("!")
|
|
|
|
%x value
|
|
%option noyywrap
|
|
%option nounput
|
|
%%
|
|
|
|
{_assignment} {
|
|
/* "=" */
|
|
PRINT ("ASSIGNMENT: %s\n", yytext);
|
|
lvalp->s = gst_parse_strdup (yytext);
|
|
BEGIN (INITIAL);
|
|
return ASSIGNMENT;
|
|
}
|
|
|
|
{_padref} {
|
|
yytext++;
|
|
PRINT ("PADREF: %s\n", yytext);
|
|
lvalp->s = gst_parse_strdup (yytext);
|
|
BEGIN (INITIAL);
|
|
return PADREF;
|
|
}
|
|
|
|
{_ref} {
|
|
PRINT ("REF: %s\n", yytext);
|
|
lvalp->s = gst_parse_strdup (yytext);
|
|
BEGIN (INITIAL);
|
|
return REF;
|
|
}
|
|
|
|
{_binref} {
|
|
gchar *pos = yytext;
|
|
while (!g_ascii_isspace (*pos) && (*pos != '.')) pos++;
|
|
*pos = '\0';
|
|
PRINT ("BINREF: %s\n", yytext);
|
|
lvalp->s = gst_parse_strdup (yytext);
|
|
BEGIN (INITIAL);
|
|
return BINREF;
|
|
}
|
|
|
|
{_identifier} {
|
|
PRINT ("IDENTIFIER: %s\n", yytext);
|
|
lvalp->s = gst_parse_strdup (yytext);
|
|
BEGIN (INITIAL);
|
|
return IDENTIFIER;
|
|
}
|
|
|
|
{_link} {
|
|
gchar *c = yytext;
|
|
PRINT ("LINK: %s\n", yytext);
|
|
c++;
|
|
if (*c) {
|
|
while (g_ascii_isspace (*c)) c++;
|
|
c = lvalp->s = gst_parse_strdup (c);
|
|
while (*c) c++;
|
|
g_assert (*--c == '!');
|
|
while (g_ascii_isspace (*--c));
|
|
*++c = '\0';
|
|
} else {
|
|
lvalp->s = NULL;
|
|
}
|
|
BEGIN (INITIAL);
|
|
return LINK;
|
|
}
|
|
|
|
{_operator} { PRINT ("OPERATOR: [%s]\n", yytext); return *yytext; }
|
|
|
|
[[:space:]]+ { PRINT ("SPACE: [%s]\n", yytext); }
|
|
|
|
. {
|
|
printf ("???: %s\n", yytext);
|
|
return *yytext;
|
|
}
|
|
|
|
%%
|