mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2024-11-30 21:51:09 +00:00
55490732be
Split plugin into features including dynamic types which can be indiviually registered during a static build. More details here: https://gitlab.freedesktop.org/gstreamer/gst-build/-/merge_requests/199 https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/661 Part-of: <https://gitlab.freedesktop.org/gstreamer/gst-plugins-good/-/merge_requests/876>
35 lines
1.1 KiB
Meson
35 lines
1.1 KiB
Meson
oss_header_locations = [
|
|
# Linux and newer BSD versions
|
|
['sys/soundcard.h', 'HAVE_OSS_INCLUDE_IN_SYS', 'OSS includes are in sys/'],
|
|
# Some old BSD versions and also newer OpenBSD versions
|
|
['soundcard.h', 'HAVE_OSS_INCLUDE_IN_ROOT', 'OSS includes are in root'],
|
|
# Some old BSD versions
|
|
['machine/soundcard.h', 'HAVE_OSS_INCLUDE_IN_MACHINE', 'OSS includes are in machine/'],
|
|
]
|
|
|
|
have_oss = false
|
|
oss_option = get_option('oss')
|
|
if not oss_option.disabled()
|
|
foreach hdr : oss_header_locations
|
|
if not have_oss
|
|
if cc.has_header(hdr[0])
|
|
cdata.set(hdr[1], 1, description: hdr[2])
|
|
have_oss = true
|
|
endif
|
|
endif
|
|
endforeach
|
|
|
|
if not have_oss and oss_option.enabled()
|
|
error('OSS plugin was enabled but soundcard.h was not found')
|
|
endif
|
|
endif
|
|
|
|
if have_oss
|
|
plugins += [library('gstossaudio',
|
|
'gstossaudio.c', 'gstossaudioelement.c', 'gstosshelper.c', 'gstosssink.c', 'gstosssrc.c',
|
|
c_args : gst_plugins_good_args,
|
|
include_directories : [configinc, libsinc],
|
|
dependencies : [gstaudio_dep, gstbase_dep],
|
|
install : true,
|
|
install_dir : plugins_install_dir)]
|
|
endif
|