mirror of
https://gitlab.freedesktop.org/gstreamer/gstreamer.git
synced 2024-07-04 13:45:52 +00:00
260a82e514
The build fails on macos with the following error:
/usr/local/Cellar/opencv/4.5.0_5/include/opencv4/opencv2/core/mat.hpp:2226:15: error: no template named 'initializer_list' in namespace 'std'
Mat_(std::initializer_list<_Tp> values);
fatal error: too many errors emitted, stopping now [-ferror-limit=]
35 warnings and 20 errors generated.
Part-of: <https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad/-/merge_requests/2368>
51 lines
1.7 KiB
Meson
51 lines
1.7 KiB
Meson
opencv_sources = [
|
|
'gstopencvutils.cpp',
|
|
'gstopencvvideofilter.cpp',
|
|
]
|
|
|
|
opencv_headers = [
|
|
'opencv-prelude.h',
|
|
'gstopencvutils.h',
|
|
'gstopencvvideofilter.h',
|
|
]
|
|
|
|
if get_option('opencv').disabled()
|
|
gstopencv_dep = disabler()
|
|
subdir_done()
|
|
endif
|
|
|
|
opencv_dep = dependency('opencv', version : '>= 3.0.0', required : false)
|
|
if not opencv_dep.found()
|
|
opencv_dep = dependency('opencv4', version : '>= 4.0.0', required : false)
|
|
endif
|
|
if opencv_dep.found()
|
|
# opencv4 seems to ship with .pc file that references non-existent include dir
|
|
# (/usr/include/opencv4/opencv instead of /usr/include/opencv4/opencv2)
|
|
# clang 10 complains about the following header in opencv4
|
|
# /usr/include/opencv4/opencv2/flann/logger.h:83:36: error: format string is not a string literal [-Werror,-Wformat-nonliteral]
|
|
gstopencv_cargs = cxx.get_supported_arguments(['-Wno-missing-include-dirs', '-Wno-format-nonliteral'])
|
|
|
|
gstopencv = library('gstopencv-' + api_version,
|
|
opencv_sources,
|
|
c_args : gst_plugins_bad_args + ['-DBUILDING_GST_OPENCV'],
|
|
cpp_args : gst_plugins_bad_args + gstopencv_cargs + ['-DBUILDING_GST_OPENCV'],
|
|
override_options : ['cpp_std=c++11'],
|
|
include_directories : [configinc, libsinc],
|
|
version : libversion,
|
|
soversion : soversion,
|
|
darwin_versions : osxversion,
|
|
install : true,
|
|
dependencies : [gstbase_dep, gstvideo_dep, opencv_dep],
|
|
)
|
|
|
|
gstopencv_dep = declare_dependency(link_with: gstopencv,
|
|
include_directories : [libsinc],
|
|
dependencies : [gstvideo_dep, opencv_dep])
|
|
|
|
install_headers(opencv_headers, subdir : 'gstreamer-1.0/gst/opencv')
|
|
elif get_option('opencv').enabled()
|
|
error('OpenCV support enabled but required dependencies were not found.')
|
|
else
|
|
gstopencv_dep = disabler()
|
|
endif
|