gstreamer/subprojects/gst-plugins-good/gst/videobox/meson.build

videobox_sources = [
  'gstvideobox.c',
]

videobox_headers = [
  'gstvideobox.h',
]

doc_sources = []
foreach s: videobox_sources + videobox_headers
  doc_sources += meson.current_source_dir() / s
endforeach

plugin_sources += {
  'videobox': pathsep.join(doc_sources)
}

if get_option('videobox').disabled()
  subdir_done()
endif

orcsrc = 'gstvideoboxorc'
if have_orcc
  orc_h = custom_target(orcsrc + '.h',
    input : orcsrc + '.orc',
    output : orcsrc + '.h',
    command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
  orc_c = custom_target(orcsrc + '.c',
    input : orcsrc + '.orc',
    output : orcsrc + '.c',
    command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  orc_targets += {'name': orcsrc, 'orc-source': files(orcsrc + '.orc'), 'header': orc_h, 'source': orc_c}
else
  orc_h = configure_file(input : orcsrc + '-dist.h',
    output : orcsrc + '.h',
    copy : true)
  orc_c = configure_file(input : orcsrc + '-dist.c',
    output : orcsrc + '.c',
    copy : true)
endif

gstvideobox = library('gstvideobox',
  videobox_sources + [orc_c, orc_h],
  c_args : gst_plugins_good_args,
  include_directories : [configinc],
  dependencies : [orc_dep, gstbase_dep, gstvideo_dep],
  install : true,
  install_dir : plugins_install_dir,
)
plugins += [gstvideobox]