gstreamer/validate/tests/check/meson.build

# tests and condition when to skip the test
validate_tests = [
  ['validate/padmonitor'],
  ['validate/monitoring'],
  ['validate/reporting'],
  ['validate/overrides']
]

test_defines = [
  '-UG_DISABLE_ASSERT',
  '-UG_DISABLE_CAST_CHECKS',
  '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_STATE_IGNORE_ELEMENTS"',
  '-DTESTFILE="' + meson.current_source_dir() + '/meson.build"',
  '-DGST_USE_UNSTABLE_API',
]

env = environment()
env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
env.set('GST_STATE_IGNORE_ELEMENTS', '')
env.set('CK_DEFAULT_TIMEOUT', '20')
env.set('GST_PLUGIN_PATH_1_0', meson.build_root())
if not meson.is_subproject()
  env.append('GST_PLUGIN_PATH_1_0', gst_dep.get_pkgconfig_variable('pluginsdir'))
endif

foreach t : validate_tests
  test_name = t.get(0)
  if t.length() == 2
    skip_test = t.get(1)
  else
    skip_test = false
  endif

  if not skip_test
    exe = executable(test_name, '@0@.c'.format(test_name),
        'validate/test-utils.c',
        c_args : gst_c_args + test_defines,
        include_directories : [inc_dirs],
        dependencies : [validate_dep, gstcheck_dep],
    )
    env.set('GST_REGISTRY',
            '@0@/@1@.registry'.format(meson.current_build_dir(), test_name))
    test(test_name, exe, env: env)
  endif
endforeach