mirror of
https://github.com/jart/cosmopolitan.git
synced 2024-05-17 19:12:41 +00:00
957c61cbbf
This change upgrades to GCC 12.3 and GNU binutils 2.42. The GNU linker appears to have changed things so that only a single de-duplicated str table is present in the binary, and it gets placed wherever the linker wants, regardless of what the linker script says. To cope with that we need to stop using .ident to embed licenses. As such, this change does significant work to revamp how third party licenses are defined in the codebase, using `.section .notice,"aR",@progbits`. This new GCC 12.3 toolchain has support for GNU indirect functions. It lets us support __target_clones__ for the first time. This is used for optimizing the performance of libc string functions such as strlen and friends so far on x86, by ensuring AVX systems favor a second codepath that uses VEX encoding. It shaves some latency off certain operations. It's a useful feature to have for scientific computing for the reasons explained by the test/libcxx/openmp_test.cc example which compiles for fifteen different microarchitectures. Thanks to the upgrades, it's now also possible to use newer instruction sets, such as AVX512FP16, VNNI. Cosmo now uses the %gs register on x86 by default for TLS. Doing it is helpful for any program that links `cosmo_dlopen()`. Such programs had to recompile their binaries at startup to change the TLS instructions. That's not great, since it means every page in the executable needs to be faulted. The work of rewriting TLS-related x86 opcodes, is moved to fixupobj.com instead. This is great news for MacOS x86 users, since we previously needed to morph the binary every time for that platform but now that's no longer necessary. The only platforms where we need fixup of TLS x86 opcodes at runtime are now Windows, OpenBSD, and NetBSD. On Windows we morph TLS to point deeper into the TIB, based on a TlsAlloc assignment, and on OpenBSD/NetBSD we morph %gs back into %fs since the kernels do not allow us to specify a value for the %gs register. OpenBSD users are now required to use APE Loader to run Cosmo binaries and assimilation is no longer possible. OpenBSD kernel needs to change to allow programs to specify a value for the %gs register, or it needs to stop marking executable pages loaded by the kernel as mimmutable(). This release fixes __constructor__, .ctor, .init_array, and lastly the .preinit_array so they behave the exact same way as glibc. We no longer use hex constants to define math.h symbols like M_PI.
331 lines
11 KiB
ArmAsm
331 lines
11 KiB
ArmAsm
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│ vi: set noet ft=asm ts=8 sw=8 fenc=utf-8 :vi │
|
|
╚──────────────────────────────────────────────────────────────────────────────╝
|
|
│ │
|
|
│ Optimized Routines │
|
|
│ Copyright (c) 1999-2022, Arm Limited. │
|
|
│ │
|
|
│ Permission is hereby granted, free of charge, to any person obtaining │
|
|
│ a copy of this software and associated documentation files (the │
|
|
│ "Software"), to deal in the Software without restriction, including │
|
|
│ without limitation the rights to use, copy, modify, merge, publish, │
|
|
│ distribute, sublicense, and/or sell copies of the Software, and to │
|
|
│ permit persons to whom the Software is furnished to do so, subject to │
|
|
│ the following conditions: │
|
|
│ │
|
|
│ The above copyright notice and this permission notice shall be │
|
|
│ included in all copies or substantial portions of the Software. │
|
|
│ │
|
|
│ THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, │
|
|
│ EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF │
|
|
│ MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. │
|
|
│ IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY │
|
|
│ CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, │
|
|
│ TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE │
|
|
│ SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE. │
|
|
│ │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#include "libc/intrin/aarch64/asmdefs.internal.h"
|
|
.yoink arm_optimized_routines_notice
|
|
|
|
#define __strncmp_aarch64 strncmp
|
|
|
|
/* Assumptions:
|
|
*
|
|
* ARMv8-a, AArch64.
|
|
* MTE compatible.
|
|
*/
|
|
|
|
#define REP8_01 0x0101010101010101
|
|
#define REP8_7f 0x7f7f7f7f7f7f7f7f
|
|
|
|
/* Parameters and result. */
|
|
#define src1 x0
|
|
#define src2 x1
|
|
#define limit x2
|
|
#define result x0
|
|
|
|
/* Internal variables. */
|
|
#define data1 x3
|
|
#define data1w w3
|
|
#define data2 x4
|
|
#define data2w w4
|
|
#define has_nul x5
|
|
#define diff x6
|
|
#define syndrome x7
|
|
#define tmp1 x8
|
|
#define tmp2 x9
|
|
#define tmp3 x10
|
|
#define zeroones x11
|
|
#define pos x12
|
|
#define mask x13
|
|
#define endloop x14
|
|
#define count mask
|
|
#define offset pos
|
|
#define neg_offset x15
|
|
|
|
/* Define endian dependent shift operations.
|
|
On big-endian early bytes are at MSB and on little-endian LSB.
|
|
LS_FW means shifting towards early bytes.
|
|
LS_BK means shifting towards later bytes.
|
|
*/
|
|
#ifdef __AARCH64EB__
|
|
#define LS_FW lsl
|
|
#define LS_BK lsr
|
|
#else
|
|
#define LS_FW lsr
|
|
#define LS_BK lsl
|
|
#endif
|
|
|
|
ENTRY (__strncmp_aarch64)
|
|
PTR_ARG (0)
|
|
PTR_ARG (1)
|
|
SIZE_ARG (2)
|
|
cbz limit, L(ret0)
|
|
eor tmp1, src1, src2
|
|
mov zeroones, #REP8_01
|
|
tst tmp1, #7
|
|
and count, src1, #7
|
|
b.ne L(misaligned8)
|
|
cbnz count, L(mutual_align)
|
|
|
|
/* NUL detection works on the principle that (X - 1) & (~X) & 0x80
|
|
(=> (X - 1) & ~(X | 0x7f)) is non-zero iff a byte is zero, and
|
|
can be done in parallel across the entire word. */
|
|
.p2align 4
|
|
L(loop_aligned):
|
|
ldr data1, [src1], #8
|
|
ldr data2, [src2], #8
|
|
L(start_realigned):
|
|
subs limit, limit, #8
|
|
sub tmp1, data1, zeroones
|
|
orr tmp2, data1, #REP8_7f
|
|
eor diff, data1, data2 /* Non-zero if differences found. */
|
|
csinv endloop, diff, xzr, hi /* Last Dword or differences. */
|
|
bics has_nul, tmp1, tmp2 /* Non-zero if NUL terminator. */
|
|
ccmp endloop, #0, #0, eq
|
|
b.eq L(loop_aligned)
|
|
/* End of main loop */
|
|
|
|
L(full_check):
|
|
#ifndef __AARCH64EB__
|
|
orr syndrome, diff, has_nul
|
|
add limit, limit, 8 /* Rewind limit to before last subs. */
|
|
L(syndrome_check):
|
|
/* Limit was reached. Check if the NUL byte or the difference
|
|
is before the limit. */
|
|
rev syndrome, syndrome
|
|
rev data1, data1
|
|
clz pos, syndrome
|
|
rev data2, data2
|
|
lsl data1, data1, pos
|
|
cmp limit, pos, lsr #3
|
|
lsl data2, data2, pos
|
|
/* But we need to zero-extend (char is unsigned) the value and then
|
|
perform a signed 32-bit subtraction. */
|
|
lsr data1, data1, #56
|
|
sub result, data1, data2, lsr #56
|
|
csel result, result, xzr, hi
|
|
ret
|
|
#else
|
|
/* Not reached the limit, must have found the end or a diff. */
|
|
tbz limit, #63, L(not_limit)
|
|
add tmp1, limit, 8
|
|
cbz limit, L(not_limit)
|
|
|
|
lsl limit, tmp1, #3 /* Bits -> bytes. */
|
|
mov mask, #~0
|
|
lsr mask, mask, limit
|
|
bic data1, data1, mask
|
|
bic data2, data2, mask
|
|
|
|
/* Make sure that the NUL byte is marked in the syndrome. */
|
|
orr has_nul, has_nul, mask
|
|
|
|
L(not_limit):
|
|
/* For big-endian we cannot use the trick with the syndrome value
|
|
as carry-propagation can corrupt the upper bits if the trailing
|
|
bytes in the string contain 0x01. */
|
|
/* However, if there is no NUL byte in the dword, we can generate
|
|
the result directly. We can't just subtract the bytes as the
|
|
MSB might be significant. */
|
|
cbnz has_nul, 1f
|
|
cmp data1, data2
|
|
cset result, ne
|
|
cneg result, result, lo
|
|
ret
|
|
1:
|
|
/* Re-compute the NUL-byte detection, using a byte-reversed value. */
|
|
rev tmp3, data1
|
|
sub tmp1, tmp3, zeroones
|
|
orr tmp2, tmp3, #REP8_7f
|
|
bic has_nul, tmp1, tmp2
|
|
rev has_nul, has_nul
|
|
orr syndrome, diff, has_nul
|
|
clz pos, syndrome
|
|
/* The most-significant-non-zero bit of the syndrome marks either the
|
|
first bit that is different, or the top bit of the first zero byte.
|
|
Shifting left now will bring the critical information into the
|
|
top bits. */
|
|
L(end_quick):
|
|
lsl data1, data1, pos
|
|
lsl data2, data2, pos
|
|
/* But we need to zero-extend (char is unsigned) the value and then
|
|
perform a signed 32-bit subtraction. */
|
|
lsr data1, data1, #56
|
|
sub result, data1, data2, lsr #56
|
|
ret
|
|
#endif
|
|
|
|
L(mutual_align):
|
|
/* Sources are mutually aligned, but are not currently at an
|
|
alignment boundary. Round down the addresses and then mask off
|
|
the bytes that precede the start point.
|
|
We also need to adjust the limit calculations, but without
|
|
overflowing if the limit is near ULONG_MAX. */
|
|
bic src1, src1, #7
|
|
bic src2, src2, #7
|
|
ldr data1, [src1], #8
|
|
neg tmp3, count, lsl #3 /* 64 - bits(bytes beyond align). */
|
|
ldr data2, [src2], #8
|
|
mov tmp2, #~0
|
|
LS_FW tmp2, tmp2, tmp3 /* Shift (count & 63). */
|
|
/* Adjust the limit and ensure it doesn't overflow. */
|
|
adds limit, limit, count
|
|
csinv limit, limit, xzr, lo
|
|
orr data1, data1, tmp2
|
|
orr data2, data2, tmp2
|
|
b L(start_realigned)
|
|
|
|
.p2align 4
|
|
/* Don't bother with dwords for up to 16 bytes. */
|
|
L(misaligned8):
|
|
cmp limit, #16
|
|
b.hs L(try_misaligned_words)
|
|
|
|
L(byte_loop):
|
|
/* Perhaps we can do better than this. */
|
|
ldrb data1w, [src1], #1
|
|
ldrb data2w, [src2], #1
|
|
subs limit, limit, #1
|
|
ccmp data1w, #1, #0, hi /* NZCV = 0b0000. */
|
|
ccmp data1w, data2w, #0, cs /* NZCV = 0b0000. */
|
|
b.eq L(byte_loop)
|
|
L(done):
|
|
sub result, data1, data2
|
|
ret
|
|
/* Align the SRC1 to a dword by doing a bytewise compare and then do
|
|
the dword loop. */
|
|
L(try_misaligned_words):
|
|
cbz count, L(src1_aligned)
|
|
|
|
neg count, count
|
|
and count, count, #7
|
|
sub limit, limit, count
|
|
|
|
L(page_end_loop):
|
|
ldrb data1w, [src1], #1
|
|
ldrb data2w, [src2], #1
|
|
cmp data1w, #1
|
|
ccmp data1w, data2w, #0, cs /* NZCV = 0b0000. */
|
|
b.ne L(done)
|
|
subs count, count, #1
|
|
b.hi L(page_end_loop)
|
|
|
|
/* The following diagram explains the comparison of misaligned strings.
|
|
The bytes are shown in natural order. For little-endian, it is
|
|
reversed in the registers. The "x" bytes are before the string.
|
|
The "|" separates data that is loaded at one time.
|
|
src1 | a a a a a a a a | b b b c c c c c | . . .
|
|
src2 | x x x x x a a a a a a a a b b b | c c c c c . . .
|
|
|
|
After shifting in each step, the data looks like this:
|
|
STEP_A STEP_B STEP_C
|
|
data1 a a a a a a a a b b b c c c c c b b b c c c c c
|
|
data2 a a a a a a a a b b b 0 0 0 0 0 0 0 0 c c c c c
|
|
|
|
The bytes with "0" are eliminated from the syndrome via mask.
|
|
|
|
Align SRC2 down to 16 bytes. This way we can read 16 bytes at a
|
|
time from SRC2. The comparison happens in 3 steps. After each step
|
|
the loop can exit, or read from SRC1 or SRC2. */
|
|
L(src1_aligned):
|
|
/* Calculate offset from 8 byte alignment to string start in bits. No
|
|
need to mask offset since shifts are ignoring upper bits. */
|
|
lsl offset, src2, #3
|
|
bic src2, src2, #0xf
|
|
mov mask, -1
|
|
neg neg_offset, offset
|
|
ldr data1, [src1], #8
|
|
ldp tmp1, tmp2, [src2], #16
|
|
LS_BK mask, mask, neg_offset
|
|
and neg_offset, neg_offset, #63 /* Need actual value for cmp later. */
|
|
/* Skip the first compare if data in tmp1 is irrelevant. */
|
|
tbnz offset, 6, L(misaligned_mid_loop)
|
|
|
|
L(loop_misaligned):
|
|
/* STEP_A: Compare full 8 bytes when there is enough data from SRC2.*/
|
|
LS_FW data2, tmp1, offset
|
|
LS_BK tmp1, tmp2, neg_offset
|
|
subs limit, limit, #8
|
|
orr data2, data2, tmp1 /* 8 bytes from SRC2 combined from two regs.*/
|
|
sub has_nul, data1, zeroones
|
|
eor diff, data1, data2 /* Non-zero if differences found. */
|
|
orr tmp3, data1, #REP8_7f
|
|
csinv endloop, diff, xzr, hi /* If limit, set to all ones. */
|
|
bic has_nul, has_nul, tmp3 /* Non-zero if NUL byte found in SRC1. */
|
|
orr tmp3, endloop, has_nul
|
|
cbnz tmp3, L(full_check)
|
|
|
|
ldr data1, [src1], #8
|
|
L(misaligned_mid_loop):
|
|
/* STEP_B: Compare first part of data1 to second part of tmp2. */
|
|
LS_FW data2, tmp2, offset
|
|
#ifdef __AARCH64EB__
|
|
/* For big-endian we do a byte reverse to avoid carry-propagation
|
|
problem described above. This way we can reuse the has_nul in the
|
|
next step and also use syndrome value trick at the end. */
|
|
rev tmp3, data1
|
|
#define data1_fixed tmp3
|
|
#else
|
|
#define data1_fixed data1
|
|
#endif
|
|
sub has_nul, data1_fixed, zeroones
|
|
orr tmp3, data1_fixed, #REP8_7f
|
|
eor diff, data2, data1 /* Non-zero if differences found. */
|
|
bic has_nul, has_nul, tmp3 /* Non-zero if NUL terminator. */
|
|
#ifdef __AARCH64EB__
|
|
rev has_nul, has_nul
|
|
#endif
|
|
cmp limit, neg_offset, lsr #3
|
|
orr syndrome, diff, has_nul
|
|
bic syndrome, syndrome, mask /* Ignore later bytes. */
|
|
csinv tmp3, syndrome, xzr, hi /* If limit, set to all ones. */
|
|
cbnz tmp3, L(syndrome_check)
|
|
|
|
/* STEP_C: Compare second part of data1 to first part of tmp1. */
|
|
ldp tmp1, tmp2, [src2], #16
|
|
cmp limit, #8
|
|
LS_BK data2, tmp1, neg_offset
|
|
eor diff, data2, data1 /* Non-zero if differences found. */
|
|
orr syndrome, diff, has_nul
|
|
and syndrome, syndrome, mask /* Ignore earlier bytes. */
|
|
csinv tmp3, syndrome, xzr, hi /* If limit, set to all ones. */
|
|
cbnz tmp3, L(syndrome_check)
|
|
|
|
ldr data1, [src1], #8
|
|
sub limit, limit, #8
|
|
b L(loop_misaligned)
|
|
|
|
#ifdef __AARCH64EB__
|
|
L(syndrome_check):
|
|
clz pos, syndrome
|
|
cmp pos, limit, lsl #3
|
|
b.lo L(end_quick)
|
|
#endif
|
|
|
|
L(ret0):
|
|
mov result, #0
|
|
ret
|
|
END(__strncmp_aarch64)
|